home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Seriousutility / Compresion / TOOLS.D81 / partition info (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  1.1 KB  |  48 lines
  1. 10 REM PARTITION INFO V1.01 06/25/91
  2. 20 PRINT"[147]"
  3. 30 INPUT"HD DEVICE NUMBER";DV
  4. 32 IFDV<8ORDV>29THENRUN
  5. 40 PRINT"OUTPUT TO PRINTER? (Y/N) ";
  6. 42 GETK$:IFK$=""THENGOTO42
  7. 44 PRINTK$:IFK$<>"Y"THENGOTO60
  8. 50 INPUT"PRINTER DEVICE NUMBER";PD
  9. 52 OPENPD,PD,0
  10. 60 OPEN15,DV,15
  11. 70 PRINT"[147]";
  12. 100 FORI=0TO254
  13. 110 PRINT#15,"G-P"+CHR$(I)
  14. 120 GET#15,PT$:PT=ASC(PT$+CHR$(0)):IFPT=0THENGOTO400
  15. 122 GET#15,X1$,PN$
  16. 130 NA$="":FORJ=1TO16
  17. 140 GET#15,N$
  18. 150 NA$=NA$+N$
  19. 160 NEXT
  20. 170 GET#15,AH$,AM$,AL$,X2$,X3$,X4$,X5$,X6$,SH$,SM$,SL$,X7$
  21. 190 PN=ASC(PN$+CHR$(0))
  22. 200 AH=ASC(AH$+CHR$(0))
  23. 210 AM=ASC(AM$+CHR$(0))
  24. 220 AL=ASC(AL$+CHR$(0))
  25. 230 SH=ASC(SH$+CHR$(0))
  26. 240 SM=ASC(SM$+CHR$(0))
  27. 250 SL=ASC(SL$+CHR$(0))
  28. 260 SB=AL+(AM*256)+(AH*(256^2))
  29. 270 SA=SB*512
  30. 280 SZ=(SL+(SM*256)+(SH*(256^2)))*512
  31. 300 PRINT"PARTITION NUMBER :";PN
  32. 302 IFPD>0THENPRINT#PD,"PARTITION NUMBER :";PN
  33. 310 PRINT"PARTITION NAME   : ";NA$
  34. 312 IFPD>0THENPRINT#PD,"PARTITION NAME   : ";NA$
  35. 320 PRINT"PARTITION TYPE   :";PT
  36. 322 IFPD>0THENPRINT#PD,"PARTITION TYPE   :";PT
  37. 330 PRINT"STARTING BLOCK   :";SB
  38. 332 IFPD>0THENPRINT#PD,"STARTING BLOCK   :";SB;
  39. 340 PRINT"STARTING ADDRESS :";SA
  40. 342 IFPD>0THENPRINT#PD,"STARTING ADDRESS :";SA
  41. 350 PRINT"PARTITION SIZE   :";SZ;"BYTES"
  42. 352 IFPD>0THENPRINT#PD,"PARTITION SIZE   :";SZ;"BYTES"
  43. 360 PRINT
  44. 362 IFPD>0THENPRINT#PD
  45. 400 NEXT
  46. 410 IFPD>0THENCLOSEPD
  47. 420 CLOSE15
  48.